Chunky Blues — 57 of 59

Scott Hammack and Jessamin Yu

Release 2

Book 4 - Outside

A man called O Side is in the Burger Shoppe. "[O Side] fiddles with the cash register." The printed name of O Side is "Outside". Understand "inside" as N Side. Understand "outside" as O Side. The description of O Side is "Mr. Outside is a burly middle-aged man stuffed into a white button-up shirt and apron, crowned with a paper hat and thick, round glasses."

O Side wears a shirt, an apron, a paper hat, and glasses.

Instead of talking to O Side while the player is not wearing shoes or the player is not wearing shirt:

say "'No shirt, no shoes, no service!'"

Instead of buying while in Burger Shoppe, try talking to O Side.

outside-hello, outside-buy-burger, outside-wheres-velvita, outside-walrus, outside-life-story, outside-really-buy-burger, outside-pay-for-burger, outside-main-squeeze, and outside-goodbye are chat nodes.

Report giving text for outside-hello: instead do nothing.

Carry out preparing outside-walrus: instead do nothing.

Carry out preparing outside-life-story: instead do nothing.

Carry out preparing outside-main-squeeze: instead do nothing.

Carry out finding responses to outside-hello:

link to outside-buy-burger;

if velvita is familiar, link to outside-wheres-velvita;

link to outside-walrus;

link to outside-main-squeeze;

link to outside-life-story;

link to outside-goodbye;

deactivate outside-life-story;

Report giving link to outside-buy-burger:

say "I want to buy a burger." instead;

Report giving text for outside-buy-burger:

if a Hamburger sandwich is not off-stage, say "'Tell you what, big guy, why don't you worry about that after you finish the one you have?'" instead;

else run a conversation from outside-really-buy-burger instead;

Report giving text for outside-really-buy-burger:

say "'That'll be fifty cents.'" instead;

Carry out finding responses to outside-really-buy-burger:

if the wealth of the cash is at least $0.50, link to outside-pay-for-burger;

link to outside-goodbye;

Report giving link to outside-pay-for-burger:

say "Here you go. (Give him $0.50.)" instead;

Report giving text for outside-pay-for-burger:

decrease the wealth of the cash by $0.50;

move a Hamburger sandwich to the player;

note the Hamburger sandwich;

say "'Enjoy!'" instead;

Report giving link to outside-wheres-velvita:

say "I'm looking for Velvita Dandyfoppe." instead;

Report giving text for outside-wheres-velvita:

activate outside-walrus;

say "'You really think a classy dame like that would be seen in a dump like this? Not likely, mac. The only way I get to see Miss Dandyfoppe is from my seat at the Walrus, just like everyone else.'";

run a conversation from outside-hello instead;

Report giving link to outside-walrus:

say "Tell me [one of][or]again [stopping]about this Walrus you mentioned." instead;

Report giving text for outside-walrus:

activate outside-life-story;

say "'You know, the Dehydrated Walrus, just a little ways north of here. Miss Dandyfoppe's main squeeze runs the joint, and he got her a plum gig as the entertainment. A gig which I myself was in the running for, might I add.' He shakes his head. 'Show business, it's all nepotism.'";

activate outside-main-squeeze;

run a conversation from outside-hello instead;

Report giving link to outside-main-squeeze:

say "Who's this main squeeze of Velvita's[one of][or] again[stopping]?" instead;

Report giving text for outside-main-squeeze:

say "'Don't you read the gossip rags, mac? Velvita's been shacking up with Timothy Elephante, the wealthy gadabout who owns half this burg, the Walrus bein[apostrophe] the crown jewel in his empire.'";

deactivate outside-life-story;

note Velvephante;

run a conversation from outside-hello instead;

Report giving link to outside-life-story:

say "All right, all right, I didn't ask for your life story." instead;

Report giving text for outside-life-story:

say "'Then take a hike, chump!'" instead;

Report giving link to outside-goodbye:

say "See you later." instead;

Report giving text for outside-goodbye:

say "'Bye now.'" instead;

Instead of talking to O Side:

say "[O Side] looks up from the register. 'What can I get you?'";

run a conversation from outside-hello.