Chunky Blues — 47 of 59

Scott Hammack and Jessamin Yu

Release 2

Book 6 - Dehydrated Walrus exterior

After going to the Dehydrated Walrus exterior for the first time:

now the printed name of the club is "Dehydrated Walrus";

now the indefinite article of the club is "the";

continue the action;

The Dehydrated Walrus can be open or closed. The Dehydrated Walrus is open.

The printed name of Dehydrated Walrus exterior is "outside the Dehydrated Walrus". The description of Dehydrated Walrus exterior is "The walls of this building are covered in painted [slogans] advertising wines, liquors, and ales. A [sign] across the entrance reads 'The Dehydrated Walrus.' [if the time of day is night]The [laughter] of the damned echoes from inside.[else]The club is quiet during the daylight hours.[end if] Dodgson Street runs east from here, and the smell of cooked [beef] wafts in from the south."

The painted slogans, Dehydrated Walrus sign, and mirthless laughter are scenery in the Dehydrated Walrus exterior. Understand "building" or "entrance" as the club when in Dehydrated Walrus exterior.

The description of the slogans is "'[one of]WINES, LIQUORS, AND CIGARS[or]BURTON MUSTY AND BASS[apostrophe] ALES ON DRAUGHT[or]LAGER[then purely at random].'"

beef is a backdrop in Dehydrated Walrus exterior. Instead of smelling in the presence of beef, say "The smell of beef is making you hungry."

Instead of listening when in Dehydrated Walrus exterior and the time of day is night, say "You hear the mirthless laughter of the damned emanating from inside the Dehydrated Walrus." Instead of listening to the mirthless laughter, try listening.

Instead of going inside from Dehydrated Walrus exterior when the Dehydrated Walrus is closed, say "The club is closed until nightfall."

Instead of going inside from Dehydrated Walrus exterior when the bouncer is in Dehydrated Walrus exterior, say "The bouncer blocks your path. 'Hey hey,' he says. 'This is an exclusive club, bub. VIPs only.'";

Instead of attacking the bouncer:

say "You attack the bouncer, but it's not exactly a fair fight. He has about two hundred pounds on you. Literally; he's sitting on you. He lets you up only on the condition that you understand you're not going to get past him.";

the crowd of people are plural-named people in Dehydrated Walrus exterior. "A crowd of people stand and stare, waiting and hoping to be let into the club." Understand "riff-raff" as the crowd of people. The description of the crowd is "Dressed in their finery, these starry-eyed hopefuls judgment by the bouncer as to whether they are worthy of entrance to the Dehydrated Walrus.";

the bouncer is a man in Dehydrated Walrus exterior. "A bouncer is stationed outside the entrance, shooing away the riff-raff." The bouncer can be spent. The description of the bouncer is "He looks like a gorilla stuffed into a suit. He occupies a large volume of space and appears quite dense, in every sense of the word." The bouncer's suit is clothing worn by the bouncer. The description of the bouncer's suit is "Stretched beyond its intended capacity." The bouncer carries a list. Instead of doing anything to the list, say "The bouncer keeps the list close to his heart, where prying eyes and fingers can't get to it."

Instead of talking to or asking or telling when the noun is the bouncer, say "'Look, buddy, I got a job to do. I don't have time to chat. If you're not on the list, I can't let you in. It's that simple.'"

Every turn while the location is Dehydrated Walrus exterior and the bouncer is visible and the crowd of people is visible:

if a random chance of 1 in 2 succeeds, say "[one of]The bouncer lets a couple of people in[or]The bouncer turns a couple of people away[or]The bouncer leers at a lady's posterior as he watches her leave[at random].";

At 4:00 AM:

if the crowd of people is visible, say "The crowd of people turn away and go home.";

remove the crowd of people from play;

if the bouncer is visible:

say "The bouncer goes inside the Dehydrated Walrus and locks the door.";

remove the bouncer from play;

now the Dehydrated Walrus is closed;

At 9:00 PM:

move the bouncer to Dehydrated Walrus exterior;

move the crowd of people to Dehydrated Walrus exterior;

if the bouncer is visible, say "A bouncer emerges from the Dehydrated Walrus just in time to start managing the crowd that has gathered.";

now the Dehydrated Walrus is open;

Before giving or showing anything to the bouncer:

let item be the noun;

if the item is a business cards, say "'Private investigator, huh? Cute. You're still not getting in.'" instead;

if the item is a book and the item is not a girlie magazine, say "'I've never been much of a reader. I'm more of a visual person, know what I mean?'" instead;

if the item is edible, say "'No thanks, I just ate.'" instead;

if the item is cash, say "'I make more than that going to the john. Dream on, dweeb.'" instead;

Instead of giving a girlie magazine (called Lucille) to the bouncer:

if the bouncer is spent, say "'Thanks, but I'm good for now.'" instead;

if the bouncer carries a girlie magazine, say "'Thanks, but I'm still working on this one.'" instead;

if the banana peel is in the location:

say "The bouncer raises an eyebrow. 'Now we're talking. Hey man, cover me for a few minutes, will ya?' He takes the magazine and starts walking toward the alley. But before he can make it there, he slips on the banana peel and hits the ground with an audible crack.[paragraph break]'My spine!' the bouncer shrieks. Hearing his cries, several other Dehydrated Walrus employees emerge from the building and carry him inside, moving his spine around a lot.[paragraph break]The crowd cheer and enter the club.";

remove the crowd from play;

remove the bouncer from play;

now Lucille is in the location;

record "hilarious injury" as achieved;

else:

say "The bouncer raises an eyebrow. 'Now we're talking. Hey man, cover me for a few minutes, will ya?' He takes the magazine and goes off into the alley.";

move Lucille to the bouncer;

move the bouncer to the blind alley;

the bouncer returns in 8 minutes from now;

the refractory period ends in 38 minutes from now;

now the bouncer is spent;

record "bribery" as achieved;

At the time when the bouncer returns:

move the bouncer to Dehydrated Walrus exterior;

if the bouncer is visible:

say "The bouncer returns to his post. Noticing you, he says, 'Ah, thanks for the reading material. They got some really fascinating articles in there.' He hands the magazine back to you.";

if the bouncer carries a girlie magazine (called Lucille), move Lucille to the player;

else:

if the bouncer carries a girlie magazine (called Lucille), move Lucille to the pile of garbage;

At the time when the refractory period ends:

now the bouncer is not spent;

After going to blind alley while the bouncer is in the blind alley:

say "The bouncer is startled. 'Hey! This is private!' With his free hand he tosses you out of the alley.";

record "voyeurism" as achieved;

move the player to Dodgson Street;

A cat is a male animal in the Dehydrated Walrus exterior. The description of the cat is "Cute." The cat has a number called wait time. Wait time of cat is 0.

Every turn when the cat is in a room (called the current space):

increment wait time of cat;

if wait time of cat is at least 3:

let lucy be {north, south, east, west};

sort lucy in random order;

repeat with ricky running through lucy:

let ethel be the room ricky from the current space;

if ethel is a room and ethel is not indoors:

silently try the cat going ricky;

if rule succeeded:

if the cat is visible:

let fred be north;

if ricky is north:

let fred be south;

else if ricky is south:

let fred be north;

else if ricky is east:

let fred be west;

else if ricky is west:

let fred be east;

say "[if the cat is seen]The[else]A[end if] [cat] arrives from [the fred].";

now the cat is seen;

else if the cat was visible:

say "[if the cat is seen]The[else]A[end if] [cat] wanders off to [the ricky].";

now the cat is seen;

now wait time of cat is 0;

break;

Instead of touching the cat, say "[The cat] purrs." Understand "pet [something]" as touching. Instead of taking the cat, say "You attempt to pick up [the cat], but he squirms out of your grasp."

Instead of attacking the cat:

now the score is -1000000;

end the story saying "Fuck you."