Chunky Blues — 26 of 59

Scott Hammack and Jessamin Yu

Release 2

Book 1 - Inventory

Instead of taking inventory:

if the player is carrying no listable things:

say "You are empty-handed. ";

else:

now all things enclosed by the player are unmarked for listing;

now all listable things carried by the player are marked for listing;

say "You are carrying ";

list the contents of the player, as a sentence, listing marked items only, tersely, including contents;

say ". ";

if the player is wearing a listable thing:

[ let x be a list of things;

repeat with y running through list of things worn by the player:

add y to x;

remove expression from x, if present;]

[ say "You are wearing [if x is empty]nothing but [an expression][else][x with indefinite articles][end if].";]

now all things enclosed by the player are unmarked for listing;

now all listable things worn by the player are marked for listing;

say "You are wearing ";

list the contents of the player, as a sentence, listing marked items only, including all contents;

say ".";

else:

say "You are wearing nothing but [an expression].";

rule succeeds.

The brown trousers are trousers worn by the player. The indefinite article of the brown trousers is "some". Understand "pants/slacks" as trousers. The description of the brown trousers is "A nondescript pair of brown trousers."

The stained shirt is a shirt worn by the player. The description of the stained shirt is "Though once quite dapper, your shirt is now spotted with stains of various colors and textures." Understand "stain/stains" as shirt.

The spectators are shoes worn by the player. The indefinite article of the shoes is "a pair of". The printed name of the spectators is "shoes". The description of the spectators is "A moderately scuffed pair of black and white spectators." Understand "shoes" as spectators.

An opaque openable small closed container called the wallet is carried by the player. The printed name of the wallet is "your wallet". The wallet is proper-named. The description of the wallet is "Your trusty friend, capable of holding all manner of bills, loose change, and other odds and sods. [if the wallet is closed]He's currently closed.[else][wallet contents]."

Some cash is a small thing in the wallet. The cash is proper-named. The cash has a price called wealth. The wealth of the cash is $1.42. The printed name of the cash is "[if wealth of the cash is $0.00]no money[else][wealth of the cash]". Understand "money" as the cash. The description of the cash is "A lump of [if wealth of the cash is at least $1.01]bills and [end if]change adding up to a total of [wealth of the cash]."

A stack of business cards is a small thing in the wallet. The description of the business cards is "'Mr. Readjustment, private investigator. No fee too big, no case too small. Bleakton Arms Apartments #146.' The cards are illustrated with a caricature of you interrogating a crying man tied to a chair." Understand "card" or "business card" as the stack of business cards.

After examining the business cards for the first time:

note your address;

try chunking your address with your name;

confirm your address;

To say wallet contents:

if the wealth of the cash is $0.00:

say "He's currently dying of starvation";

else if the wealth of the cash is less than $10.00:

say "He's been looking a bit undernourished lately, but never mind that";

The jaunty fedora is a hat worn by the player. The description of the fedora is "This fine hat was acquired at the haberdashery of one Tobias d'Ochreville. It's a pleasing shade of tan[if the trousers are worn by the player] which smartly complements your brown trousers[end if]. [garbage hat]." Understand "hat" as the fedora.

[The wristwatch is clothing worn by the player. The description of the wristwatch is "According to [if the wristwatch is worn by the player]your[else]the[end if] wristwatch, it's [time of day]." Understand "watch" as the wristwatch.]

To say garbage hat:

if the player is not wearing the fedora:

say "You gaze at it wistfully and wish it were in its rightful place atop your head";

else:

say "Having it atop your head makes you feel like the cat's pajamas[if the player is in the pile of garbage], despite being buried in a pile of garbage[end if]";

Before inserting anything into a small container:

unless the noun is small, say "[The noun] will not fit in [the second noun]." instead.

The note is a small thing in the wallet. The note can be V's or Velvita's. The note is V's. Understand "note from V" as the note. The printed name of the note is "[if not familiar]handwritten note[else]note from V". The description of the note is "Hastily scribbled in [a Velvita]'s flowery handwriting are these words: 'Meet me after the show. -V'".

After examining the note when alphabet soup is listed in STM:

remember the note;

forget alphabet soup;

if the ring is identified:

now the note is Velvita's;

whisper "Your memory of alphabet soup coalesces into the memory of [the noun].";