Chunky Blues — 4 of 59

Scott Hammack and Jessamin Yu

Release 2

Book 3 - General Actions

[ Unwiedly things, unreachable backdrops ]

Instead of taking an unwieldy thing, say "[The item described] [if the noun is plural-named]are[else]is[end if] too unwieldy to lug around with you."

Before doing anything with a backdrop (called x):

if the action requires a touchable noun and x originates in a room:

if the room originated in by x is not the location, say "You'll have to get a little closer to [the item described] to do that." instead;

continue the action.

Instead of asking or telling, try talking to the noun.

After examining anything for the first time:

now the noun is familiar;

continue the action.

After examining a notable thing:

note the noun;

continue the action.

Sobering up is an action applying to nothing.

Understand "sober" or "sober up" or "get sober" as sobering up.

Instead of sobering up:

if the player is hung over, say "Easier said than done!";

else say "You're sober enough already."

Conversation target is a person that varies.

To converse with (target - a person) on (subject - a chat node):

now conversation target is target;

run a conversation from subject;

now conversation target is nothing;

Offending is an action applying to one thing. Unoffending is an action applying to one thing.

To offend (prude - a person):

now prude is offended;

To unoffend (prude - a person):

now prude is not offended;

Instead of drinking anything, try eating the noun.

Instead of swearing obscenely:

say "Back at ya, Clyde.";

record "potty mouth" as achieved;

Understand "fuck you/off" as swearing obscenely. Understand "balls" or "crap" or "bollocks" or "feck" or "dang" or "whoops" or "crud" or "fiddlesticks" as swearing mildly.

Before swearing obscenely for the eighth time:

record "sailor" as achieved;

continue the action.

Before swearing mildly for the eight time:

record "Flanders" as achieved;

continue the action.

After examining a book:

whisper "To read a book, specify how many pages to read (ex. READ 12 PAGES OF BOOK). This will advance time by one minute per page.";

Reading it for is an action applying to one number and one carried thing. Understand "read [number] pages/page in/of [book]" as reading it for.

Check reading it for:

if the second noun is not a book, try examining the second noun instead;

if the second noun is for sale and the bookseller is in the location, say "The bookseller screeches, 'This ain't a library!'" instead;

if read pages of the second noun is at least total pages of the second noun:

say "You've already finished reading [the second noun]." instead.

Carry out reading it for:

say "You [if read pages of the second noun is greater than 0]resume[else]begin[end if] reading [the second noun].";

repeat with y running from 1 to the number understood:

increase read pages of the second noun by 1;

increase time of day by 1 minute;

if y is at least total pages of the second noun:

break;

say "Time passes...";

Report reading it for:

if read pages of the second noun is at least total pages of the second noun:

say "You finish reading [the second noun].";

award the bonus for the second noun;

else:

say "You've now read [read pages of the second noun in words] page[if read pages of the second noun is greater than 1]s[end if] out of [total pages of the second noun in words]."

To award the bonus for (x - a book):

if x is a girlie magazine:

record "reading it for the articles" as achieved;

else:

increase STM capacity by 1;

say "You feel that you've broadened your mind.";

record "literati" as achieved;

To say his:

if the item described is plural-named:

say "their";

else if the item described is male:

say "his";

else if the item described is female:

say "her";

else:

say "its";

To say him:

if the item described is plural-named:

say "them";

else if the item described is male:

say "him";

else if the item described is female:

say "her";

else:

say "it";

Talking to is an action applying to one thing. Understand "talk to/with [something]" or "talk [something]" as talking to.

Check talking to:

if the noun is yourself:

if the number of people enclosed by the location is greater than 1:

say "Talking to oneself is the first sign of madness, you know." instead;

else:

say "Here you are now, by yourself, talking to yourself. That's chaos theory!";

record "chaos theory" as achieved instead;

else if the noun is not a person:

say "[The noun] prove[unless the noun is plural-named]s[end if] not to be [unless the noun is plural-named]a [end if]stimulating conversational partner[if the noun is plural-named]s[end if]." instead;

Report talking to:

say "[The noun] do[unless the noun is plural-named]es[end if]n't dignify that with a response."

Asking anyone about anything is conversing. Telling anyone about anything is conversing. Instead of conversing, try talking to the noun.

Fucking is an action applying to one touchable thing. Understand "fuck [something]" as fucking.

Check fucking:

if the noun is yourself:

say "Please, this is neither the time nor the place.";

record "self-gratification" as achieved;

stop the action;

if the noun is a person:

say "Not without [his] informed consent!";

record "attempted sexual assault" as achieved;

stop the action;

else:

say "Not to pass judgment, but that sort of interaction is beyond the scope of this game.";

record "pansexuality" as achieved;

Instead of eating an inedible thing, say "[if the noun is a person]Sorry, it's not that kind of game.[else]You're not that hungry."

Vomiting is an action applying to nothing.

Understand "vomit" or "barf" or "puke" or "hurl" or "ralph" or "upchuck" or "blow chunks" as vomiting.

Instead of vomiting:

say "[if the vomit is known]You've done your share of that already, thank you very much.[else][one of]You're not bulimic enough.[or]You can't just vomit on command like some kind of trained goat![or]'You're so FAT!' you shout at yourself, but nothing happens.[at random][line break]";

record "attempted bulimia" as achieved;